int num = 100;
int maxspeed = 12;
int avoidRadius = 40;
int tailLength = 2;
int runsPerLoop = 3*num;

Agent[] agents = new Agent[num];

void setup(){
  size(800, 450);
  background(20);
  framerate(30);
  for (int i = 0; i < num; i++) agents[i] = new Agent();
  stroke(0,255,0);
  ellipseMode(CENTER);
}

void draw(){
  agents[0].chaser = true;

  //fade effect
  fill(20, 30);
  noStroke();
  rect(0,0,width, height);

  //Draw the agents
  for(int i=0; i<runsPerLoop; i++){
    int m = (int)random(num);
    agents[m].run();
    for (int j=1; j<tailLength; j++){
      strokeWeight(j);
      if (agents[m].chaser) stroke(180+(sin(agents[m].direction)+1)*30, 50, 10);
      else stroke(60,100+(cos(agents[m].direction)+1)*40,100+(cos(agents[m].direction)+1)*40);
      if(dist(agents[m].tail[j][0],agents[m].tail[j][1], agents[m].tail[j-1][0],agents[m].tail[j-1][1])<maxspeed){
        line(agents[m].tail[j][0],agents[m].tail[j][1], agents[m].tail[j-1][0],agents[m].tail[j-1][1]);
      }
    }
  }
  
  //Check for chasers, swap chaser states if none found
  int chasers = 0;
  for (int ii=0; ii<num; ii++) if(agents[ii].chaser == true) chasers++;
  if (chasers >= num) {
    for (int iii=0; iii<num; iii++) agents[iii].chaser = false;
    noStroke();
    fill(random(200,250), random(200,250), 200, 40);
    for (int jj = 700; jj>0; jj-=50)
      ellipse(agents[0].x, agents[0].y, jj, jj);
  }
}

class Agent {
  float x, y;
  float speed, direction;
  float[][] tail = new float[tailLength][2];
  boolean chaser = false;

  Agent(){
    x= random(width);
    y= random(height);
    speed = .2*maxspeed;
    direction = random(2*PI);
    for (int i=0; i<tailLength; i++){
      tail[i][0]= x;
      tail[i][1]= y;
    }
  }

  void run(){
    if (chaser) {
      avoidRadius = 120;
      chase();      
    }
    else avoid();
    move();
  }

  void avoid(){
    //check all Agents
    for(int i=0; i<num; i++){
      //skip Agent that is yourself
      if (((agents[i].x-x) == 0) && ((agents[i].y-y)==0)) break;
      //for everyone else, see if they're close to you
      if ((dist(agents[i].x, agents[i].y, x, y)<avoidRadius)&(x>0 & x<width & y>0 & y<height)){
        if ((agents[i].chaser) & (y-agents[i].y<0)) direction = atan((x-agents[i].x)/(y-agents[i].y))+PI+random(.2);
        else if ((agents[i].chaser) & (y-agents[i].y>0)) direction = atan((x-agents[i].x)/(y-agents[i].y))+random(.2);
        else if (!(agents[i].chaser)){
          direction = agents[i].direction+random(-PI/20, PI/20);
        }
      }
    }
  }

  void chase(){
    //Check each agent
    for(int k=0; k<num; k++){
      //If there is one that is close, it becomes a chaser (includes yourself in each iteration)
      if ((abs(agents[k].x-x) < .5) && (abs(agents[k].y-y) < .5)) agents[k].chaser = true;
      //if there is a non-chaser nearby...
      if (!(agents[k].chaser) & (dist(agents[k].x, agents[k].y, x, y)<avoidRadius) & (x>0 & x<width & y>0 & y<height)){
        if ((y-agents[k].y)<0) direction = atan((x-agents[k].x)/(y-agents[k].y));
        else direction = atan((x-agents[k].x)/(y-agents[k].y))+PI;
      }
    }    
  }

  void move(){
    x += (sin(direction) * speed);
    y += (cos(direction) * speed);

    //wrap Y and X axis
    if (y<0) y+=height;
    if (y>height) y-=height;
    if (x<0) x+=width;
    if (x>width) x-=width;
    constrain(x, 0, width);
    constrain(y, 0, height);

    for (int i=1; i<tailLength; i++){
      tail[i-1][0]= tail[i][0];
      tail[i-1][1]= tail[i][1];
    }
    tail[tailLength-1][0] = x;
    tail[tailLength-1][1] = y;
  }
}