// Walking Motion

int num = 100;
int range = 24;
int frameSpeed = 10;
float optionX;
float optionY;
boolean debug = false;

float[] ax = new float[num];
float[] ay = new float[num]; 
float[] endpoint = {380,380};

void setup() 
{
  size(400, 400);
  for(int i=0; i<num; i++) {
    ax[i] = 50;
    ay[i] = 50;
  }
  framerate(frameSpeed);
  stroke(255,0,0);
}

void draw() 
{
  background(51);
  
  // Draw the goal
  stroke(40,100,100);
  fill(40,100,100);  
  ellipse(endpoint[0], endpoint[1], 10, 10);

  
  // Shift all elements 1 place to the left
  for(int i=1; i<num; i++) {
    if (debug) print(ax[i] + " ");
    ax[i-1] = ax[i];
    ay[i-1] = ay[i];
  }
  if (debug) println();

  optionX = ax[num-1] + random(-range, range);
  optionY = ay[num-1] + random(-range, range);

  // Determine if the optionX and Y points are closer to the endpoint
  if ((abs(optionX-endpoint[0]) <= abs(ax[num-1]-endpoint[0])) && 
     (abs(optionY-endpoint[1]) <= abs(ay[num-1]-endpoint[1]))) {
    ax[num-1] = optionX;
    ay[num-1] = optionY;
  } 
  
  // if the new coordinates aren't better, stay put
  else {
    stroke(100,100,50);
    line(ax[num-1], ay[num-1], optionX, optionY);
    ax[num-1] = ax[num-2];
    ay[num-1] = ay[num-2];
  }

  // Constrain all points to the screen
  ax[num-1] = constrain(ax[num-1], 0, width);
  ay[num-1] = constrain(ay[num-1], 0, height);
 
  // Draw a line connecting the points
  for(int i=1; i<num; i++) {    
    float val = float(i)/num * 204.0 + 51;
    stroke(0,val,val);
    line(ax[i-1], ay[i-1], ax[i], ay[i]);
  }
}