int menuChoice = 1;
String lines[];
Vector species;
float squareSize, range;
String crops[] = {
  "Alfalfa","Apple","Apple1","Bean","Blueberry","Lentil","Pineapple","Potato","Rice","Rice1","Wheat"};

void setup(){
  PFont font = loadFont("BenguiatITCbyBT-Bold-48.vlw");
  squareSize = 0;
  species = new Vector();
  framerate(15);
  size(1000,800); //800x 600 is nice
  textFont(font,18);
  rectMode(CENTER);
  int xSquares = 1;
  parseText();

  //figure out biggest squares that will fit on your screen, given screensize & dataset
  //putting in a 100 pixel border
  int counter = 1;
  boolean fits = false;
  while (!fits){
    squareSize = (height-200)/counter;
    xSquares = (int)((width-200)/squareSize);
    int totalSquares = counter * xSquares;
    if (totalSquares >= species.size()) fits = true;
    counter++;
  }
  range = squareSize/3;
  //march through array of species and assign coords
  for (int i =0; i < species.size(); i++){
    float xCenter = 100+squareSize/2 + squareSize*(i%xSquares);
    float yCenter = 100+squareSize/2 + squareSize*(floor(i/xSquares));
    ((Species)species.get(i)).defineCoords(xCenter, yCenter);
  }
}

void draw(){
  background(50,50,0);
  menu();
  stroke(155);
  textAlign(CENTER);
  for (int i=0; i<species.size();i++){
    float rectSize = 5+ 10*(log(((Species)species.get(i)).freqTally+1));
    fill(50,100,0);
    rect(((Species)species.get(i)).xCenter, ((Species)species.get(i)).yCenter, rectSize, rectSize);
    fill(100,125,0);
    text(((Species)species.get(i)).freqTally, ((Species)species.get(i)).xCenter, ((Species)species.get(i)).yCenter+5);
  }
  writeOnSpecies();
}

void menu(){
  textSize(14);
  textAlign(LEFT);
  for (int i=0; i<crops.length; i++){
    if (i==menuChoice) fill(240);
    else fill(120);
    text(crops[i],10+i*80,20);
  }
  if (mousePressed && mouseY <= 20){
    menuChoice = floor((mouseX-10)/81);
    setup();
  }
}

void writeOnSpecies(){
  noStroke();
  textSize(20);
  fill(255,120,120);
  textAlign(CENTER);
  for (int i=0; i< species.size(); i++){
    float x = ((Species)species.get(i)).xCenter;
    float y = ((Species)species.get(i)).yCenter;
    //Working here to fix word spot start
    float textStart = (18 * ((Species)species.get(i)).name.size())/-2;
    if (abs(mouseX-x) < range & abs(mouseY-y) < range){
      for (int j = 0; j<((Species)species.get(i)).name.size(); j++){
        text((String)((Species)species.get(i)).name.get(j), x, textStart+y+(j*20));
      }
    }
  }
}

void parseText(){
  lines = loadStrings(crops[menuChoice] + ".csv"); //formatted: spn,"name",frequency /n from CNRCD.dbf & ACRCD.dbf
  for (int i = 0; i<lines.length; i++){  //compose species list from lines array
    // Parse out xxx, as spn
    Integer temp = new Integer(lines[i].substring(0,lines[i].indexOf(",")));
    int spn = temp.intValue();
    // Parse out ,"xxx" as species name
    String name = lines[i].substring(1+lines[i].indexOf("\""),lines[i].lastIndexOf("\""));
    // Parse out ",xxx as frequency
    Integer temp1 = new Integer(lines[i].substring(1+lines[i].lastIndexOf(","),lines[i].length()));
    int freq = temp1.intValue();

    if (i == 0) species.add(new Species(spn,name,freq));  //first line is always a new critter
    else {                           //if it's not the first critter check to see if you've found a new one
      boolean dupeFound = false;
      for (int j = 0; j<species.size(); j++){      //check for duplicates...
        if (spn == ((Species)species.get(j)).spn){ //go through list and compare spn to species.spn
          ((Species)species.get(j)).addName(name, freq); //if there is a species created just add the name to the list
          dupeFound = true;
          break;
        }
      }
      if (!dupeFound) species.add(new Species(spn, name, freq));
    }
  }
}

class Species{
  int spn; //species number -- unique 
  ArrayList name = new ArrayList();  //list of common names around the world
  int freqTally = 0; //What part of the world's crop is represented by this species
  float xCenter, yCenter;

  Species(int num, String name, int freq){
    spn = num;
    addName(name, freq);
  }

  void addName(String entry, int freq){
    name.add(entry);
    freqTally += freq;
  }

  void defineCoords(float x, float y){
    xCenter = x;
    yCenter = y;
  }
}