// consider gradient on GridBox

String lines[];
String[] filelist = {  //this set is everything but wheat
  "Alfalfa","Allium","Amaranth","Ananas","Apple","Avocado","Barley","Bean","Beta","Blueberry","Brassica","Bromus","Carrot","Celery","Chickpea","Citrus","Clover","Cotton","Cucumis","Cucurbit","Cuphea","Cynodon","Eggplant","Festuca","Fig","Flax","Fragaria","Grape","Guava","Hazelnut","Hops","Ipomoea","Lathyrus","Lentil","Lespedez","Lesquer","Lettuce","Limnanth","Litchi","Lotus","Lupin","Maize","Mango","Melilotu","Mint","Musa","Oat","Panicum","Papaya","Pea","Peanut","Pear","Peppers","Pilinut","Poa","Potato","Prunus","Quince","Quinoa","Radish","Rambutan","Ribes","Rice","Rubus","Rye","Ryegrass","Safflower","Sesame","Soybean","Spinach","Starfruit","Sugarcane","Sunflower","Tobacco","Tomato","Vigna"};
//String[] filelist = {  //this set is missing mega crops
//  "Alfalfa","Allium","Amaranth","Ananas","Apple"};
Crop[] crop = new Crop[filelist.length];
float xMax = 0;
float yMax = 0;
float zMax = 0;
float rotY = .5;
float rotX = 0;
int gridDims = 256;
PFont font;
DecimalFormat f;
int scrX, scrY;
boolean mouseIsOver;
boolean xyVisible = false;
Crop NULLcrop = new Crop();
Crop highlitCrop = NULLcrop;

void setup(){
  font = loadFont("BenguiatITCbyBT-Bold-48.vlw");
  f = new DecimalFormat("#.#");
  framerate(15);
  size(800,600,P3D);
  for (int i=0; i<filelist.length; i++) crop[i] = new Crop();
  parseText();
  calibrateGridDims();
}

void draw(){
  pushMatrix();
  translate(3*width/5, height/2, 0);
  background(140);
  scale(1.2);
  rotateY(rotY);
  rotateX(rotX);
  drawGrid();
  showCropNodes();
  popMatrix();
  drawGUI();
}

void drawGUI(){
  textFont(font, 12);
  textAlign(LEFT);
  for (int i=0; i<filelist.length; i++){
    fill(crop[i].x,crop[i].y,crop[i].z);
    text(filelist[i], 10+65*(floor(i/30)), 15+15*(i%30));
  }
  pushMatrix();
  translate(10,height-100);
  textFont(font, 16);
  fill(255);
  text(highlitCrop.name,0,0);
  text("Species: " + highlitCrop.spn.size(),0,20);
  text("Individuals: " + highlitCrop.id.size(),0,40);
  text("Locales: " + highlitCrop.geono.size(),0,60);
  text(f.format(100*(highlitCrop.wild/(float)highlitCrop.id.size())) + "% Wild",0,80);
  popMatrix();
}

void drawGrid(){
  noFill();
  stroke(100);
  box(gridDims);
  fill(255);
  textAlign(CENTER);
  textFont(font,12);
  text("0",-gridDims/2,gridDims/2+10,gridDims/2);  //Label Origin
  text(f.format(xMax),gridDims/2,gridDims/2+10,gridDims/2);
  text("Locales",0,gridDims/2+10,gridDims/2);
  pushMatrix();
  translate(-gridDims/2,0,gridDims/2);
  rotateZ(3*PI/2);
  text("IDs",0,0,0);
  text(f.format(yMax),gridDims/2,0,0);
  popMatrix();
  pushMatrix();
  translate(-gridDims/2,gridDims/2+10,-gridDims/2);
  rotateY(3*PI/2);
  text(f.format(zMax)+"%",0,0,0);
  text("%Wild",gridDims/2,0,0);
  popMatrix();
}

void calibrateGridDims(){
  for (int j=0; j<filelist.length; j++){
    if (crop[j].geono.size() > xMax) xMax = crop[j].geono.size();
    if (crop[j].id.size() > yMax) yMax = crop[j].id.size();
    if ((100*(crop[j].wild/(float)crop[j].id.size())) > zMax) zMax = 100*(crop[j].wild/(float)crop[j].id.size());
  }
  for (int i=0; i<filelist.length; i++){
    crop[i].x = gridDims*(crop[i].geono.size()/xMax);
    crop[i].y = gridDims*(crop[i].id.size()/yMax);
    crop[i].z = gridDims*((100*(crop[i].wild/(float)crop[i].id.size()))/zMax);
  }
}

void showCropNodes(){
  pushMatrix();
  translate(-gridDims/2,gridDims/2,gridDims/2);  //moves to the origin 0,0,0
  if (xyVisible) drawXY();
  for (int i=0; i<crop.length; i++){
    scrX = (int)screenX(crop[i].x,-crop[i].y,-crop[i].z);
    scrY = (int)screenY(crop[i].x,-crop[i].y,-crop[i].z);
    if ((abs(mouseX-scrX)+abs(mouseY-scrY))<8) mouseIsOver = true;
    else mouseIsOver = false;
    if (mouseIsOver || crop[i] == highlitCrop){
      highlitCrop = crop[i];
      stroke(255,255,0);
      fill(200);
      textAlign(LEFT);
      pushMatrix();
      translate(crop[i].x,-crop[i].y,-crop[i].z);
      rotateX(-rotX);
      rotateY(-rotY);
      text(crop[i].name,10,0,0);
      popMatrix();
      line(crop[i].x,-crop[i].y,-crop[i].z,crop[i].x,0,-crop[i].z); //line to x,z plane
      line(crop[i].x,0,-crop[i].z,crop[i].x,0,0); //x value line
      line(crop[i].x,0,-crop[i].z,0,0,-crop[i].z); //y value line
    }
    pushMatrix();
    translate(crop[i].x,-crop[i].y,-crop[i].z);
    fill(crop[i].x,crop[i].y,crop[i].z);
    //    fill(abs(255-crop[i].x),abs(255-crop[i].y),abs(255-crop[i].z));
    noStroke();
    if(mouseIsOver) box(10);
    else box(4);
    popMatrix();
  }
  popMatrix();
}

void parseText(){
  print("Parsed: ");
  for (int j=0; j<filelist.length; j++){
    crop[j].name = filelist[j];
    lines = loadStrings(filelist[j] + "ACRCD.csv"); //SPNNO, GEONO, ACCID, WILDNess(0-2)
    for (int i = 0; i<lines.length; i++){  //skip first line -- column headings
      String column[] = lines[i].split(",");
      crop[j].spn.add(column[0]);
      crop[j].geono.add(column[1]);
      crop[j].id.add(column[2]);
      if (column[3].equals("Wild")) crop[j].wild++;
      if (column[3].equals("Breeder's line")) crop[j].bred++;
    }
    print(filelist[j] + "...");
  }
}

void mouseDragged(){
  rotY += (mouseX - pmouseX) * 0.01;
  rotX += (pmouseY - mouseY) * 0.01;
}

void keyReleased(){
  if (key == 'r') {
//    rotY=.5;
//    rotX=0;
    xyVisible = false;
  }
  if (key == '1'){
    xyVisible = true;
  }
}

void drawXY(){
  pushMatrix();
  translate(0,0,6);
  fill(200);  
  rect(0,-gridDims,gridDims,gridDims);
  noStroke();
  fill(125,125,50);
  for (int i=0; i<crop.length; i++){
    beginShape(QUADS);
    vertex(crop[i].x-1.5,-crop[i].y-1.5,1);
    vertex(crop[i].x-1.5,-crop[i].y+1.5,1);
    vertex(crop[i].x+1.5,-crop[i].y+1.5,1);
    vertex(crop[i].x+1.5,-crop[i].y-1.5,1);
    endShape();
    beginShape(QUADS);
    vertex(crop[i].x-1.5,-crop[i].y-1.5,-1);
    vertex(crop[i].x-1.5,-crop[i].y+1.5,-1);
    vertex(crop[i].x+1.5,-crop[i].y+1.5,-1);
    vertex(crop[i].x+1.5,-crop[i].y-1.5,-1);
    endShape();
  }
  popMatrix();
}