String lines[];

String[] filelist = {  
  "Alfalfa","Allium","Amaranth","Ananas","Apple","Avocado","Barley","Bean","Beta","Blueberry","Brassica","Bromus","Carrot","Celery","Chickpea","Citrus","Clover","Cotton","Cucumis","Cucurbit","Cuphea","Cynodon","Eggplant","Festuca","Fig","Flax","Fragaria","Grape","Guava","Hazelnut","Hops","Ipomoea","Lathyrus","Lentil","Lespedez","Lesquer","Lettuce","Limnanth","Litchi","Lotus","Lupin","Maize","Mango","Melilotu","Mint","Musa","Oat","Panicum","Papaya","Pea","Peanut","Pear","Peppers","Pilinut","Poa","Potato","Prunus","Quince","Quinoa","Radish","Rambutan","Ribes","Rice","Rubus","Rye","Ryegrass","Safflower","Sesame","Soybean","Spinach","Starfruit","Sugarcane","Sunflower","Tobacco","Tomato","Vigna"};
Crop[] crop = new Crop[filelist.length];
KohonenSet klist = new KohonenSet();
float cropCriteria[][];
PFont font;
color colorArray[];
final color BACKGROUND = color(0);
DecimalFormat f;
Comparator bmuComp = new cropBmuComparator();

void setup(){
  size(1000,750);
  f = new DecimalFormat("#.#");
  font = loadFont("ArialMT-16.vlw");
  textFont(font,10);
  for (int i=0; i<crop.length; i++) crop[i] = new Crop();
  parseText();
  assignSortCriteria();
  klist.kset = cropCriteria;
  klist.initWeights(1,350,6);
  colorArray = new color[klist.numWeights];
  for (int i=0; i<klist.numWeights; i++){
    colorArray[i] = color(random(210),100+random(155), random(80));
  }
  klist.equalizeSortData();
  noStroke();
}

void draw(){
  background(BACKGROUND);
  pushMatrix();
  translate(140,12);
  drawCriteriaLabels();
  translate(0,2);
  klist.drawListMap(colorArray);
  translate(-130,0);
  klist.drawBmuLabels();
  popMatrix();
  klist.train();
}

void assignSortCriteria(){
  cropCriteria = new float[crop.length][6];
  for (int i=0; i<crop.length; i++){
    cropCriteria[i][0] = crop[i].spn.size();
    cropCriteria[i][1] = crop[i].geono.size();
    cropCriteria[i][2] = crop[i].id.size();
    cropCriteria[i][3] = crop[i].wild/(float)crop[i].id.size();
    cropCriteria[i][4] = crop[i].bred/(float)crop[i].id.size();
    cropCriteria[i][5] = crop[i].cultivar/(float)crop[i].id.size();
  }  
}

void drawCriteriaLabels(){
  text("Number of species",0,0);
  text("Number of geolocales",130,0);
  text("Number of individuals",260,0);
  text("Percent that are Wild", 390,0);
  text("Percent that are Bred", 520,0);
  text("Percent that are cultivars", 650,0);
}

void parseText(){
  print("Parsed: ");
  for (int j=0; j<filelist.length; j++){
    crop[j].name = filelist[j];
    lines = loadStrings(filelist[j] + "ACRCD.csv");
    for (int i = 0; i<lines.length; i++){
      String column[] = lines[i].split(",");
      crop[j].spn.add(column[0]);
      crop[j].geono.add(column[1]);
      crop[j].id.add(column[2]);
      if (column[3].equals("Wild")) crop[j].wild++;
      if (column[3].equals("Breeder's line")) crop[j].bred++;
      if (column[3].contains("cultivar")) crop[j].cultivar++;
    }
    print(filelist[j] + "...");
  }
}