// --------------------------------------------------- 
// University of California Santa Barbara
// Media Arts and Technology
// MAT 259 | Visualizing Information | Winter 2011
//
// Patrick Rudolph
// Project 3 | Animation
//
// Level 1 data structures
// --------------------------------------------------- 

class Level1 extends Circle {
  // aesthetics
  String src;
  PImage img;
  float fixRot;
  
  // level 1 data
  ArrayList[] data = new ArrayList[dayMax+5]; // contains raw data from file
  ArrayList recent = new ArrayList(); // data for the last period(default:30) days = trend
  int maxCount;  // max number of items
  
  // level 2 data
  Level2[] dewey = new Level2[10];
  float deweySum;
  
  
  public Level1(Level1 parent,String name,String src,float x,float y,float radius,float fixRot) {
    super(parent,name,x,y,radius);
    this.fixRot = fixRot;
    this.src = src;
    if(src != null) this.img = loadImage(src+".png"); 
    maxCount = 0;

    if(parent != null) {      
      // create level 2 circles
      for(int i = 0; i < dewey.length; i++) {
        String n = ""+i*100;
        if(i==0) n = "000"; 
        dewey[i] = new Level2(this,n,i*100,sin(TWO_PI*i/11+fixRot),-cos(TWO_PI*i/11+fixRot),0);
      }
      
      // initialize array for raw data
      for(int i=0;i<data.length;i++) {
        data[i] = new ArrayList();
      }
      
      // load data from file
      loadData();
    } 
  }
  
  
  void loadData() {
    String[] temp = loadStrings(src+".txt");
    
    try {
      maxCount = Integer.parseInt(temp[temp.length-1]);
  
      for(int i=0;i<maxCount;i++) {
        String[] columns = temp[i].split(",");
        
        int col1 = Integer.parseInt(columns[0]); // column 0 - days since 2006-01-01
        boolean dewey = false;     // dewey = true, non-dewey = false
        int col2 = 0;        // column 1 - dewey class
        
        if(!columns[1].equals("null")) { // dewey != null
          dewey = true;
          col2 = Integer.parseInt(columns[1]);
        }
        
        data[col1].add( new Item( dewey,col2 ) );
      }
    } catch (Exception E){
      println("Error while loading data: "+E);
      return;
    }    
  }
  
  
  void add(int d) { 
    // remove data older than period(default:30) days
    if(recent.size() >= period) {  // recent is full (after first period(default:30) days)
      int diff = recent.size()-period+1;
      for(int i = 0; i < diff; i++) {
        parent.sum -= ((Integer)recent.get(0)).intValue();
        sum -= ((Integer)recent.remove(0)).intValue();
      }
    }
    
    if(!data[d].isEmpty()) { // there are checkouts for day d
    
      int num = data[d].size();  // number of checkouts for day d

      // add to level 1 
      recent.add(num);
      parent.sum += num;
      sum += num;

      boolean[] dirty = new boolean[10];
      for(int i=0;i<10;i++) dirty[i] = false;
      
      // add to level 2
      for(int i=0;i<num;i++) {
        Item item = (Item) data[d].get(i); // grab each checkout for day d
        
        if(item.dewey) { // item is a dewey item
          int number = item.deweyClass/100;
          dewey[number].add(d,1);
          dirty[number] = true;
        }
      }
      for(int i=0;i<dewey.length;i++) {
        if(dirty[i] == false) {
          dewey[i].add(d,0);
        }
      }
      
    }
    else { // no checkouts for day d
      // add to level 1
      recent.add(0);
      // add to level 2
      for(int i=0;i<dewey.length;i++) {
        dewey[i].add(d,0);
      }
    }
  }
  
  
  public void draw() {
    lineOn = false;
    
    if(parent != null) {      
      // data
      if(parent.sum != 0) this.share = sum / parent.sum;
      else this.share = 0;

      this.radius = 30+share*180;
      
      // resize
      this.distance = 200+radius/1.9+2;
      this.x = initX*distance;
      this.y = initY*distance;      
      if(src != null && radius <= 80) this.img = loadImage(src+"_small.png");
      else if(src != null && radius > 80) this.img = loadImage(src+".png");
      
      // sum dewey items
      deweySum = 0;
      for(int i=0;i<dewey.length;i++) deweySum += dewey[i].sum;
      
      // draw children
      for(int i=0;i<dewey.length;i++) {
        dewey[i].draw();
        if(dewey[i].mouseInside()) drawLine();
      }

    }

    // draw
    super.draw();
    
  }

  
  void drawLine() {
    if( parent != null ) {
      stroke(cCircle3);
      strokeWeight(20);
      line(0,0,x,y);
      lineOn = true;
    }
  }
  
  
  void drawImg() {
    try {
      image(img,x,y,radius,radius);
    } catch (Exception E){
      println("Error while loading image: "+E);
      return;
    }  
  }
  
  
  void drawCircles() {
    noStroke();
    
    if( mouseInside() ) fill(cCircle1,100);
    else fill(cCircle1,50);
    ellipse(x,y,radius*1.2+5,radius*1.2+5); // outer circle
    
    fill(cCircle2,100);
    ellipse(x+1,y+1,radius*1.07,radius*1.07); // shadow of inner circle
    
    super.drawCircles();  // creamy yellow circle
  }
  
}